feat(nixos): add pikachu homepage guest

configs/nixos/modules/services/homepage.nix

@@ -0,0 +1,135 @@
+{
+  config,
+  lib,
+  registry,
+  ...
+}:
+let
+  cfg = config.modules.services.homepage;
+
+  mkRegistryPath = registryName: host: entry: "registry.${registryName}.${host}.${entry}";
+
+  homepageEntries = lib.concatLists (
+    lib.mapAttrsToList (
+      host: entries:
+      lib.mapAttrsToList (entry: homepage: {
+        inherit host entry homepage;
+        composite = registry.join host entry;
+      }) entries
+    ) registry.homepage
+  );
+
+  mkHref = item:
+    if item.homepage.href != null then
+      item.homepage.href
+    else if (item.composite.route or null) != null && item.composite.route.port != null then
+      let
+        scheme = if item.composite.route.forceSSL then "https" else "http";
+      in
+      "${scheme}://${item.composite.route.domain}"
+    else
+      throw "${mkRegistryPath "homepage" item.host item.entry} needs href or a matching TCP route entry";
+
+  mkServiceAttrs = item:
+    lib.filterAttrs (_: value: value != null) {
+      href = mkHref item;
+      inherit (item.homepage) description icon;
+    };
+
+  sortedEntries = lib.sort (left: right: left.homepage.name < right.homepage.name) homepageEntries;
+
+  insertEntry = acc: item:
+    acc
+    // {
+      ${item.homepage.tab} = (acc.${item.homepage.tab} or { })
+        // {
+          ${item.homepage.section} = (acc.${item.homepage.tab}.${item.homepage.section} or [ ]) ++ [
+            { ${item.homepage.name} = mkServiceAttrs item; }
+          ];
+        };
+    };
+
+  entriesByTab = lib.foldl' insertEntry { } sortedEntries;
+
+  tabOrder = [
+    "Apps"
+    "Download"
+    "System"
+  ];
+
+  orderedTabs = tabOrder ++ lib.filter (tab: !lib.elem tab tabOrder) (lib.attrNames entriesByTab);
+
+  mkTab = tab:
+    let
+      sections = entriesByTab.${tab};
+    in
+    {
+      ${tab} = map (section: { ${section} = sections.${section}; }) (lib.attrNames sections);
+    };
+
+  homepageServices = map mkTab (lib.filter (tab: lib.hasAttr tab entriesByTab) orderedTabs);
+in
+{
+  options.modules.services.homepage = {
+    enable = lib.mkEnableOption "Homepage Dashboard";
+
+    listenPort = lib.mkOption {
+      type = lib.types.port;
+      default = 8082;
+      description = "Port for Homepage to bind to.";
+    };
+
+    allowedHosts = lib.mkOption {
+      type = lib.types.listOf lib.types.str;
+      default = [ "home" ];
+      description = "Host headers accepted by Homepage.";
+    };
+  };
+
+  config = lib.mkIf cfg.enable {
+    services.homepage-dashboard = {
+      enable = true;
+      openFirewall = true;
+      inherit (cfg) listenPort;
+      allowedHosts = lib.concatStringsSep "," cfg.allowedHosts;
+      services = homepageServices;
+      settings = {
+        title = "Tracion";
+        theme = "dark";
+        color = "slate";
+        showStats = false;
+        hideVersion = true;
+        bookmarksStyle = "icons";
+        useEqualHeights = true;
+        layout = {
+          Apps = {
+            style = "row";
+            columns = 1;
+            tab = "Apps";
+            Media = {
+              style = "row";
+              columns = 2;
+            };
+            Files = {
+              style = "row";
+              columns = 2;
+            };
+            Other = {
+              style = "row";
+              columns = 3;
+              iconsOnly = true;
+            };
+          };
+          Download = {
+            style = "row";
+            columns = 1;
+            tab = "Download";
+          };
+          System = {
+            tab = "System";
+          };
+        };
+      };
+    };
+  };
+}

configs/nixos/modules/services/reverse-proxy.nix

@@ -21,8 +21,7 @@ let
       inherit host entry;
       name = route.domain;
       value = {
-        forceSSL = true;
-        enableACME = true;
+        inherit (route) forceSSL enableACME;
         locations."/".proxyPass = mkBackend address route;
       };
     };