{
  config,
  lib,
  pkgs,
  inputs,
  ...
}:
# The shared foundation for every host and guest.
let
  stateVersion = "26.05";
in
{
  imports = [ inputs.home-manager.nixosModules.home-manager ];

  options.user = {
    name = lib.mkOption {
      type = lib.types.str;
      default = "alexion";
      description = ''
        Primary interactive user for this system.
        This drives the system account and Home Manager user together.
      '';
    };
  };

  config = {
    system.stateVersion = stateVersion;

    nixpkgs.config.allowUnfree = true;
    nix.settings.experimental-features = [
      "nix-command"
      "flakes"
    ];

    users.users.${config.user.name} = {
      isNormalUser = true;
      extraGroups = [
        "wheel"
        "storage"
      ];
    };

    users.groups.storage.gid = 10000;

    time.timeZone = "America/New_York";
    i18n.defaultLocale = "en_GB.UTF-8";

    home-manager = {
      useGlobalPkgs = true;
      useUserPackages = true;
      users.${config.user.name} = {
        home.username = config.user.name;
        home.homeDirectory = "/home/${config.user.name}";
        home.stateVersion = stateVersion;
        home.packages = with pkgs; [
          eza
          wget
        ];
      };
    };

    registry.shell-shortcut.${config.networking.hostName} = {
      ls = {
        command = "eza -alg --color=always --group-directories-first --icons=always";
        abbreviation = false;
      };
      ll = {
        command = "eza -lg --color=always --group-directories-first --icons=always";
        abbreviation = false;
      };
      lt = {
        command = "eza -aT -I '.git' --color=always --group-directories-first --icons=always";
        abbreviation = false;
      };
      ".." = "cd ..";
      "..." = "cd ../..";
      "...." = "cd ../../..";

      cp = "cp -v";
      tarnow = "tar -acf ";
      untar = "tar -zxvf ";
      wget = "wget -c ";
      grep = "grep --color=auto";
      fgrep = "fgrep --color=auto";
      egrep = "egrep --color=auto";
      jctl = "journalctl -p 3 -xb";

      update = "sudo nixos-rebuild switch --flake .#${config.networking.hostName}";
      cleanup = "sudo nix-collect-garbage -d";
    };

    modules.shell.fish.enable = lib.mkDefault true;
    modules.shell.fish.defaultShell = lib.mkDefault true;
    modules.shell.tmux.enable = lib.mkDefault true;
    modules.shell.nvim.enable = lib.mkDefault true;
    modules.shell.git.enable = lib.mkDefault true;
    modules.shell.yazi.enable = lib.mkDefault true;
  };
}