refactor(reverse-proxy): use route registry

lib/default.nix

@@ -16,7 +16,6 @@ let
   serviceIdentityRegistry = import ./service-identities.nix { inherit lib; };
   registry = import ./registry.nix { inherit lib self; };
   networkEndpoints = import ./network-endpoints.nix { inherit lib; };
-  reverseProxyRoutes = import ./reverse-proxy-routes.nix { inherit lib; };
 
   collectNixFiles =
     dir:
@@ -35,16 +34,11 @@ let
       ) (builtins.readDir dir)
     );
 
-  specialArgs =
-    let
-      networkFleetEndpoints = self.lib.networkEndpoints.collectFleetEndpoints self.nixosConfigurations;
-    in
-    {
-      inherit inputs networkFleetEndpoints self;
-      my = self.lib;
-      registry = self.lib.registry.collect { hosts = self.nixosConfigurations; };
-      reverseProxyFleetRoutes = self.lib.reverseProxyRoutes.collectFleetRoutes self.nixosConfigurations networkFleetEndpoints;
-    };
+  specialArgs = {
+    inherit inputs self;
+    my = self.lib;
+    registry = self.lib.registry.collect { hosts = self.nixosConfigurations; };
+  };
 
   bridgeName = id: "br-vlan${toString id}";
 
@@ -54,7 +48,6 @@ let
       self
       specialArgs
       bridgeName
-      reverseProxyRoutes
       ;
   };
 
@@ -95,7 +88,6 @@ in
     bridgeName
     registry
     networkEndpoints
-    reverseProxyRoutes
     ;
 
   inherit (guests) deriveMac guest;

lib/guests.nix

@@ -3,7 +3,6 @@
   self,
   specialArgs,
   bridgeName,
-  reverseProxyRoutes,
 }:
 let
   inherit (lib) escapeShellArg mapAttrsToList;
@@ -130,9 +129,13 @@ let
             Left null, this guest contributes no address to the address registry.
           '';
         };
-        reverseProxy = reverseProxyRoutes.mkRouteOptions {
-          subject = "guest route";
-          enableDefault = false;
+        reverseProxy = {
+          enable = lib.mkEnableOption "a reverse-proxy route for this guest";
+
+          route = lib.mkOption {
+            type = self.lib.registry.definitions.route.type;
+            description = "Route registry entry published for this guest.";
+          };
         };
         mounts = lib.mkOption {
           type = lib.types.attrsOf (
@@ -279,14 +282,7 @@ let
 
         registry.address.${config.networking.hostName}.${machineName} = lib.mkIf (cfg.address != null) cfg.address;
 
-        modules.reverse-proxy.routes.${machineName} = lib.mkIf cfg.reverseProxy.enable (
-          reverseProxyRoutes.routeFields (
-            cfg.reverseProxy
-            // lib.optionalAttrs (cfg.reverseProxy.backend == null && cfg.reverseProxy.endpoint == null) {
-              endpoint = "${config.networking.hostName}-${machineName}";
-            }
-          )
-        );
+        registry.route.${config.networking.hostName}.${machineName} = lib.mkIf cfg.reverseProxy.enable cfg.reverseProxy.route;
 
         assertions = [
           {

lib/registry.nix

@@ -28,6 +28,23 @@ let
     in
     nameValuePair (registryName name) (import path { inherit lib; })
   ) (filterAttrs (name: type: type == "regular" && hasSuffix ".nix" name) (builtins.readDir (self + "/registry")));
+  join = registry: host: entry:
+    filterAttrs (_name: value: value != null) (
+      mapAttrs (registryName: _registry: (registry.${registryName}.${host} or { }).${entry} or null) definitions
+    );
+
+  collectData =
+    { hosts }:
+    mapAttrs (
+      registryName: _registry:
+      mapAttrs (hostName: host: host.config.registry.${registryName}.${hostName} or { }) hosts
+    ) definitions;
+
+  withOperations = registry:
+    registry
+    // {
+      join = host: entry: join registry host entry;
+    };
 in
 {
   inherit definitions;
@@ -36,10 +53,5 @@ in
     options.registry = mapAttrs (_name: registry: registryOption registry) definitions;
   };
 
-  collect =
-    { hosts }:
-    mapAttrs (
-      registryName: _registry:
-      mapAttrs (hostName: host: host.config.registry.${registryName}.${hostName} or { }) hosts
-    ) definitions;
+  collect = args: withOperations (collectData args);
 }

lib/reverse-proxy-routes.nix

@@ -1,129 +0,0 @@
-{ lib }:
-let
-  mkRouteOptions =
-    {
-      name ? null,
-      subject ? "route",
-      enableDefault ? true,
-    }:
-    {
-      enable = lib.mkOption {
-        type = lib.types.bool;
-        default = enableDefault;
-        description = "Whether this reverse-proxy ${subject} is active.";
-      };
-
-      host = lib.mkOption (
-        {
-          type = lib.types.str;
-          description = "Primary hostname served by this reverse-proxy ${subject}.";
-        }
-        // lib.optionalAttrs (name != null) {
-          default = name;
-          defaultText = lib.literalMD "the route attribute name";
-        }
-      );
-
-      aliases = lib.mkOption {
-        type = lib.types.listOf lib.types.str;
-        default = [ ];
-        description = "Additional hostnames served by this reverse-proxy ${subject}.";
-      };
-
-      path = lib.mkOption {
-        type = lib.types.str;
-        default = "/";
-        description = "URL path prefix proxied by this reverse-proxy ${subject}.";
-      };
-
-      backend = lib.mkOption {
-        type = lib.types.nullOr lib.types.str;
-        default = null;
-        description = "Full HTTP backend URL that receives proxied traffic.";
-      };
-
-      endpoint = lib.mkOption {
-        type = lib.types.nullOr lib.types.str;
-        default = null;
-        description = "Fleet network endpoint key used to derive the backend URL.";
-      };
-
-      port = lib.mkOption {
-        type = lib.types.nullOr (lib.types.ints.between 1 65535);
-        default = null;
-        example = 3923;
-        description = "Backend TCP port used with the fleet network endpoint.";
-      };
-
-      scheme = lib.mkOption {
-        type = lib.types.str;
-        default = "http";
-        description = "Backend URL scheme used with the fleet network endpoint.";
-      };
-
-      tls = lib.mkOption {
-        type = lib.types.bool;
-        default = true;
-        description = "Whether to serve this reverse-proxy ${subject} with ACME-backed TLS.";
-      };
-
-      websockets = lib.mkOption {
-        type = lib.types.bool;
-        default = false;
-        description = "Whether to enable websocket proxy headers for this reverse-proxy ${subject}.";
-      };
-    };
-
-  routeFields = route: {
-    inherit (route)
-      host
-      aliases
-      path
-      backend
-      endpoint
-      port
-      scheme
-      tls
-      websockets
-      ;
-  };
-
-  endpointBackend = endpoints: route:
-    let
-      endpoint = endpoints.${route.endpoint} or (
-        throw "Unknown reverse-proxy endpoint `${route.endpoint}`. Known endpoints: ${lib.concatStringsSep ", " (lib.attrNames endpoints)}"
-      );
-    in
-    "${route.scheme}://${endpoint.address}:${toString route.port}";
-
-  resolvedRouteFields = endpoints: route:
-    let
-      routeWithBackend =
-        if route.backend != null then
-          route
-        else if route.endpoint != null && route.port != null then
-          route // { backend = endpointBackend endpoints route; }
-        else
-          throw "Reverse-proxy route `${route.host}${route.path}` needs either backend or endpoint plus port.";
-    in
-    routeFields routeWithBackend;
-
-  collectFleetRoutes =
-    hosts: endpoints:
-    lib.concatMapAttrs (
-      hostName: host:
-      lib.mapAttrs' (
-        routeName: route: lib.nameValuePair "${hostName}-${routeName}" (resolvedRouteFields endpoints route)
-      ) host.config.modules.reverse-proxy.routes
-    ) hosts;
-in
-{
-  inherit collectFleetRoutes mkRouteOptions resolvedRouteFields routeFields;
-
-  routeType = lib.types.submodule (
-    { name, ... }:
-    {
-      options = mkRouteOptions { inherit name; };
-    }
-  );
-}