feat(network): add fleet endpoint registry

lib/default.nix

@@ -14,6 +14,7 @@ let
     ;
 
   serviceIdentityRegistry = import ./service-identities.nix { inherit lib; };
+  networkEndpoints = import ./network-endpoints.nix { inherit lib; };
   reverseProxyRoutes = import ./reverse-proxy-routes.nix { inherit lib; };
 
   collectNixFiles =
@@ -36,6 +37,7 @@ let
   specialArgs = {
     inherit inputs self;
     my = self.lib;
+    networkFleetEndpoints = self.lib.networkEndpoints.collectFleetEndpoints self.nixosConfigurations;
     reverseProxyFleetRoutes = self.lib.reverseProxyRoutes.collectFleetRoutes self.nixosConfigurations;
   };
 
@@ -85,6 +87,7 @@ in
     mkHost
     mkHosts
     bridgeName
+    networkEndpoints
     reverseProxyRoutes
     ;
 

lib/guests.nix

@@ -131,6 +131,18 @@ let
             guest takes its address by DHCP, keeping IP management at the router.
           '';
         };
+        endpoint = {
+          address = lib.mkOption {
+            type = lib.types.nullOr lib.types.str;
+            default = null;
+            example = "10.23.20.126";
+            description = ''
+              Expected IP address assigned outside NixOS for this guest's
+              network endpoint. Left null, this guest contributes no endpoint to
+              the fleet endpoint registry.
+            '';
+          };
+        };
         reverseProxy = reverseProxyRoutes.mkRouteOptions {
           subject = "guest route";
           enableDefault = false;
@@ -278,6 +290,10 @@ let
       config = lib.mkIf cfg.enable {
         sops.secrets = lib.genAttrs cfg.secrets (_: { });
 
+        modules.network.endpoints.${machineName} = lib.mkIf (cfg.endpoint.address != null) {
+          inherit (cfg.endpoint) address;
+        };
+
         modules.reverse-proxy.routes.${machineName} = lib.mkIf cfg.reverseProxy.enable (
           reverseProxyRoutes.routeFields cfg.reverseProxy
         );

lib/network-endpoints.nix

@@ -0,0 +1,42 @@
+{ lib }:
+let
+  endpointOptions = {
+    address = lib.mkOption {
+      type = lib.types.str;
+      example = "10.23.20.126";
+      description = "Expected IP address assigned outside NixOS for this network endpoint.";
+    };
+  };
+
+  endpointType = lib.types.submodule {
+    options = endpointOptions;
+  };
+
+  endpointFields = endpoint: {
+    inherit (endpoint) address;
+  };
+
+  collectFleetEndpoints =
+    hosts:
+    lib.concatMapAttrs (
+      hostName: host:
+      let
+        cfg = host.config.modules.network;
+        hostEndpoint = lib.optionalAttrs (cfg.endpoint.address != null) {
+          ${hostName} = endpointFields cfg.endpoint;
+        };
+        guestEndpoints = lib.mapAttrs' (
+          endpointName: endpoint: lib.nameValuePair "${hostName}-${endpointName}" (endpointFields endpoint)
+        ) cfg.endpoints;
+      in
+      hostEndpoint // guestEndpoints
+    ) hosts;
+in
+{
+  inherit
+    collectFleetEndpoints
+    endpointFields
+    endpointOptions
+    endpointType
+    ;
+}