refactor(flake): split root output wiring

src/flake/apps.nix

@@ -0,0 +1,41 @@
+{
+  inputs,
+  lib,
+  formatter,
+  system,
+}:
+let
+  pkgs = inputs.nixpkgs.legacyPackages.${system};
+in
+{
+  fix = {
+    type = "app";
+    program = lib.getExe (
+      pkgs.writeShellApplication {
+        name = "fix";
+        runtimeInputs = [
+          formatter
+          pkgs.statix
+          pkgs.deadnix
+        ];
+        text = ''
+          treefmt
+          statix fix \
+            --ignore 'configs/nixos/hosts/*/hardware-configuration.nix' \
+            --ignore 'src/xatu/testdata/**' \
+            --ignore third_party \
+            .
+          deadnix --edit \
+            --exclude \
+              configs/nixos/hosts/neogaia/hardware-configuration.nix \
+              configs/nixos/hosts/pikachu/hardware-configuration.nix \
+              configs/nixos/hosts/zeus/hardware-configuration.nix \
+              src/xatu/testdata \
+              third_party \
+            -- .
+          treefmt
+        '';
+      }
+    );
+  };
+}

src/flake/default.nix

@@ -0,0 +1,34 @@
+{
+  lib,
+  inputs,
+  self,
+  root,
+  system,
+}:
+let
+  dotfiles = import ../dotfiles {
+    inherit
+      inputs
+      lib
+      self
+      ;
+    root = root + "/configs/nixos";
+  };
+in
+{
+  formatter.${system} =
+    (import ./formatter.nix {
+      inherit inputs system;
+    }).config.build.wrapper;
+
+  apps.${system} = import ./apps.nix {
+    inherit
+      inputs
+      lib
+      system
+      ;
+    formatter = self.formatter.${system};
+  };
+
+  inherit (dotfiles) nixosConfigurations;
+}

src/flake/formatter.nix

@@ -0,0 +1,12 @@
+{ inputs, system }:
+inputs.treefmt-nix.lib.evalModule inputs.nixpkgs.legacyPackages.${system} {
+  projectRootFile = "flake.nix";
+
+  programs.nixfmt.enable = true;
+
+  settings.formatter.nixfmt.excludes = [
+    "configs/nixos/hosts/*/hardware-configuration.nix"
+    "src/xatu/testdata/*.nix"
+    "third_party/**"
+  ];
+}